请选择 进入手机版 | 继续访问电脑版

Excel完美论坛

 找回密码
 立即注册

QQ登录

只需一步,快速开始

快捷登录

 
版块
版块
班级
班级
班级
班级
其它
其它
查看: 9092|回复: 5

函数高级班教学大纲

  [复制链接]

1万

积分

17

技术分

509

鲜花

管理员

佛山小老鼠

Rank: 18Rank: 18Rank: 18Rank: 18Rank: 18

财富币
694504
学费币
3164
推广币
214919
学员红花
0
注册时间
2014-12-17

管理员基础技巧讲师函数讲师VBA编程讲师 透视表讲师

    购买在线课件和视频
    报班咨询联系电话
    Tel:186-6424-3619
    联系人:佛山小老鼠
    在线网络开设YY班级
    函数初级班
    函数中级班
    函数高级班
    VBA编程初级班
    VBA编程中级班
    VBA编程高级班
    透视表班
    290集视频
    525集excel视频大全
    189集免费excel视频
发表于 2014-12-19 00:22:05 | 显示全部楼层 |阅读模式
一键分享 一键分享
函数高级班教学大纲
声明:报名后不以任何理由退款,思索好再报名
上课内容:见下面
上课时间:见每次开班的详细时间
讲师:天津丫头
上课教室:YY频道141797学费:600元
课时16节 每节2小时
备注:二年内,重学免费,滚动开班,没有学过函高,没有数组根底不建议报班,报班发放配套的视频

第1讲:多维援用认识

Offset函数:
=OFFSET(C3,1,0,1,1)第一次任务提取一个单元格
=OFFSET(C3,1,0,2,1)第二次任务提取两个单元格

=OFFSET(C3,1,0,{1,2},1) 将两个任务同时交给OFFSET去完成,提取到的是三个单元格,并且是成

阶梯式呈现。

汇总:关于offset完成的两次任务,我们无法经过普通公式停止汇总,由于存在躲藏数据,所以这

里必需用到降维才干够停止汇总。
        支持降维函数:sumif  subtotal
=SUM(SUMIF(OFFSET(D3,1,0,{1,2,3},1),">0"))
sumif对OFFSET每次任务停止单独汇总,得到的是三个结果,此时曾经停止了降维了,将三个结果

降到了一个平面上,再由sum进汇总

------------------------
多表汇总;
1.INDIRECT({"一月","二月","三月","四月"}&"!r1c"&COLUMN(A1),) 对每张表的A1单元格停止调


2.=OFFSET(INDIRECT({"一月","二月","三月","四月"}&"!r1c"&COLUMN(A1),),9,0) offset从每张

表的A1单元格停止偏移到汇总数所在单元格位置,
3.对多表的汇总数据停止降维处置:N
N(OFFSET(INDIRECT({"一月","二月","三月","四月"}&"!r1c"&COLUMN(A1),),9,0))
4.sum最后停止汇总;

=SUM(N(OFFSET(INDIRECT({"一月","二月","三月","四月"}&"!r1c"&COLUMN(A1),),9,0)))
5.最后拖拽公式完成多列汇总。


OFFSET对多表的多列汇总数据停止同时汇总效果:
=SUM(SUMIF(OFFSET(INDIRECT({"一月","二月","三月","四月"}&"!r1c"&COLUMN

(A1),),9,0,1,4),">0"))
-----------------------------------------------------------

函高第2讲二分法认识
**二分法讲解**
【提示】
1】基于lookup查找方式是精确查找与模糊查找同时并存为前提,所以lookup默以为您的数据源曾经做了升序
排列。即使您没升序排列,lookup也自以为数据源为升序排序。
所以lookup以为第二参数中最上方/左方的数据最小,最右方/下方数据最大
2】lookup函数永远玩的是兄妹恋:查找比本人小的美女组中最大的妹妹为心怡人选。
遇大则退,宁缺毋滥准绳。

一:中值的查找方法:
数据源内的元素个数为奇数个数时:(元素个数+1)/2 =中值位置
数据源内的元素个数为偶数个数时:(元素个数 /2)= 中值位置
二:二分法查找规律:
1】 当二分法查找时,查到值大于中值时,再二分法向后找.
2】 当二分法查找时,查到值小于中值时,再二分法向前查找.
案例:
数据源:正常排序下的情况
成果 等级
0 不及格
60 及格
70 良好
80 优秀
此时返回的结果为正确的。但是一旦数据源没有按请求停止升序排序则会有下面的情况
成果 等级
70 良好
60 及格
80 优秀
0 不及格
查找值:75 ;公式:=LOOKUP(75,{70;60;80;0},{"良好";"及格";"优秀";"不及格"})
返回结果:及格??????
查找原理:
1.首先找到第一次中值位置:为60所在位置 ,lookup将查找值75与中值比照,遵照第一条规律:查找值大于
中值则向后/右查找
2.经过第一次二分法后,只需80和0没有停止查找了。在这两个值中其中值为80,此时中值大于查找值,则遵
循第二条规律:查找值小于中值则向上/左找。也就是返回到方才第一次查找时分的数据源区域,契合条件的
只需60所在位置,也就返回的是“及格”了。是不是有点出乎预料哈!
------------------------------------------------------

3】当二分法查找时,查到的值等于中值时,再逐一向后查,不断到呈现不相等时回止,并返回最后一个相等值对
应的数据.
案例:数据源
数据源 等级
7 A
5 B
5 C
10 D
8 E
7 F
7 G
7 H
5 I
7 J
6 K

查找值:7  公式:=LOOKUP(7,{7;5;5;10;8;7;7;7;5;7;6},
{"A";"B";"C";"D";"E";"F";"G";"H";"I";"J";"K"}) 结果为 H ????????

4】当中值位置与边境堆叠时,中止比照,此时假设查找值大于中值,则返回中位值;假设查找值小于中值,
则返回中值左侧数值。假设左侧数值不存在,返回#N/A*********************************
数据源:上一个案例中的数据源
查找值:9 公式:=LOOKUP(9,{7;5;5;10;8;7;7;7;5;7;6},
{"A";"B";"C";"D";"E";"F";"G";"H";"I";"J";"K"}) 返回K ????
查找值:4 公式:=LOOKUP(4,{7;5;5;10;8;7;7;7;5;7;6},
{"A";"B";"C";"D";"E";"F";"G";"H";"I";"J";"K"})
5】假设查找值小于第二参数中的一切值(最小中值),就会返回#N/A 错误值
例如:上一个案例中 查找值为 4 的情况。

备注(数组里有5个元素时,中值就是第三个,假设只需4个元素,那么中值就是第二个元素)
6】关于错误值的处置:****************************
1)当第一参数大于第二参数中的一切值(最大中值)此时lookup忽略第二参数中的错误值
=LOOKUP(1,0/({0,"老鼠","大家",0,0,"完",0,0,0}<>""),{0,"老鼠","大家",0,0,"完",0,0,0})
2)当第一参数不能满足大于第二参数中的一切值(最大中值)此时不忽略错误值。
=LOOKUP(0,0/({0,"老鼠","大家",0,0,"完",0,0,0}<>""),{0,"老鼠","大家",0,0,"完",0,0,0})
1)案例:返回最后一条不为空数据
INDEX函数作业一:变形记
公式特性:一参数大于被除数
2)案例:返回最后一条不为空数据
公式特性:一参数不大于被除数

3)提示:您可别问我假设第一参数小于被除数怎样计算?
被除数曾经是最小值了,您比最小值都小那不是遵照第五条规律吗?直接返回错误值#N/A根本没有
小妹可找呀!!!
------------------------------------------------------

第3节简单的提取数字
一.数字在右边没有字母
        解法1:=MIDB(B11,SEARCHB("?",B11),99)
        解法2=RIGHT(B11,2*LEN(B11)-LENB(B11))

二.数字在左边有字母
        =LEFT(B17,COUNT(0/LEFT(B17,ROW($1:$9))))
三.数字在中间没有字母且是连续的
        解法=MIDB(B32,SEARCHB("?",B32),2*LEN(B32)-LENB(B32))
四.数字在中间有字母且是连续的
        =MID(B39,MATCH(,0/MID(B39,ROW($1:$30),1),),COUNT(0/MID(B39,ROW($1:$30),1)))
        总结:count牛,match牛,lookup牛,为什么呢?,由于它们不怕错误值
        =-LOOKUP(,-MID(B39,MIN(FIND(ROW($1:$10)-1,B39&5/19)),ROW($1:$30)))

------------------------------------------------------
第四讲:LOOKUP函数

一:为什么我的Lookup公式不对
解:lookup第二参数请求升序排序,否则进入二分法查找了。这里文本值也需求排序,文本是按照拼音停止 排序的,要想不用排序,就要根据二分法原理停止处置。
1.处置方法:停止绝对精确性判别,
        公式={"一级";"二级";"三级";"四级";"五级";"六级";"七级";"八级"}="八级"
这样就可以找到独一值,
2.逻辑值转数值  =0/(G1:G8=A2)

3.完好公式:=LOOKUP(1,0/(G1:G8=A2),H1:H8)

----------------
二:双条件查找;
=LOOKUP(1,0/((E4=A4:A7)*(F3=B4:B7)),C4:C7)

----------------
三:打破lookup第3参数又有数据又有单元格援用
公式:=LOOKUP(A2,{0,60,70,80,90},CHOOSE({1,2,3,4,5},0,2,3,4,A2/10*1.5))

1.第二参数为各区间最小值
2.由于第三参数触及到本领的运算,也就是单元格本领参与运算,而在lookup第三参数中通常我们用的是单 元格区域或常量数组,而单元格区域不能再次援用本人本身停止二次运算,而常量数组中又不可以运用单元 格作为数据参与运算,所以这里就要用函数数组方法返回多条数据作为lookup第三参数,这样就讲单元格本 事作为函数的参数停止运用了。

2.第三参数运用数组方式,由choose一次性返回,构建lookup第三参数返回值
提示:在常量数组中是无法直接运用单元格链接的,可以将单元格链接作为参数停止运用,所以这里用 choose。
3.不用IF停止第三参数返回,累呀,
        公式:=LOOKUP(A2,{0,60,70,80,90},IF({1,1,1,1,0},IF({1,1,1,0},IF({1,1,0},IF ({1,0},0,2),3),4),A2/10*1.5))



---------------------------------------

四:Lookup+Find完成模糊查找

公式:
=LOOKUP(FIND(A13,"搬运工叉车司机清洁工厨师帮厨电工保安门卫食堂"),{1,4,8},{"搬运工","叉车司机"," 后勤"})

1.构建find函数查找值所在字符串:将一切查找值停止链接起来即可。
2.lookup第二参数
        1表示搬运工呈如今第一个字符位置,
        4表示叉车司机呈如今第四个字符位置
        8表示后勤部的一切岗位呈如今第八个字符位置
3.返回值:就是工种的三个类别即可。

五:lookup + find 经典数组用法
        公式:=IFERROR(LOOKUP(9E+307,FIND($E$2:$E$24,A2),$E$2:$E$24),"其他")
1.应用谁包含谁的规律来肯定谁做第一参数谁做第二参数,
2.摘要包含业务员名单,所以肯定摘要做find函数的数据源字符串,业务员名单做find函数查找字符
3.find结果得到的是错误值与独逐一个有效数值的数组,正好作为lookup第二参数
4.lookup应用二分法中第一参数大于第二参数一切数值则返回做后一个有效数据所在位置对应的第三参数,

---------------------------------------

函数高级第5节Indirect函数

一:提取最后数字位置
=right(A2,2*len()-lenb())
=RIGHT(A2,count())
=COUNT(-MID(A3,ROW(1:20),1))

第一个数字呈现位置;=MIN(FIND(ROW(1:10)-1,A2&5/19))
最后数字位置:=MATCH(1,N(INDIRECT("z"&MID(A2,ROW($1:$20),1))))
提取数据位数:
=MATCH(1,N(INDIRECT("z"&MID(A2,ROW($1:$20),1))))-MIN(FIND(ROW(1:10)-1,A2&5/19))+1

公式:=MID(A2,MIN(FIND(ROW($1:$10)-1,A2&5/19)),MATCH(1,N(INDIRECT("z"&MID(A2,ROW($1: $20),1))),1)-MIN(FIND(ROW($1:$10)-1,A2&5/19))+1)

1.找到第一个数字位置
MIN(FIND(ROW($1:$10)-1,A2&5/19))

2.找到最后一个数字位置
MATCH(1,N(INDIRECT("z"&MID(A2,ROW($1:$20),1))),1)

3.电话号位数
MATCH(1,N(INDIRECT("z"&MID(A2,ROW($1:$20),1))),1)-MIN(FIND(ROW($1:$10)-1,A2&5/19))+1
加1的原理:执行头尾都不减


二:多表条件求和(留意工作表称号容错处置)
1.假设位置分歧,则可以运用indirect函将三个表的固定第一个停止调取后汇总。

=SUM(N(INDIRECT(ROW($1:$3)&"月!b2")))
=SUM(N(INDIRECT(ROW($1:$3)&"月!b"&ROW(A2))))
2.位置不分歧则必需用条件停止匹配再汇总

=SUM(SUMIF(INDIRECT(ROW($1:$3)&"月!a:a"),A2,INDIRECT(ROW($1:$3)&"月!b:b")))
1.三张工作表的条件所在区域,
=INDIRECT(ROW($1:$3)&"月!a:a")
2.求和区域
INDIRECT(ROW($1:$3)&"月!b:b")
3.多表条件汇总,sumif对三张工作表分别汇总并降维为一维,最后sum汇总
=SUM(SUMIF(INDIRECT(ROW($1:$3)&"月!a:a"),A2,INDIRECT(ROW($1:$3)&"月!b:b")))

提示;假设工作表称号是文本且无规律,则用常量数组,且留意运用容错。

三:VLOOKUP一对多查询
借助辅助单元格区域完成
=IFERROR(VLOOKUP($E$2&ROW(A1),$A$2:$C$27,3,),"")
数组公式完成
1.区域动态提取
=INDIRECT("B2:B"&ROW($B$2:$B$27)) 作为countif统计区域运用。
2.统计查找值所呈现的次数
=COUNTIF(INDIRECT("B2:B"&ROW($B$2:$B$27)),$E$2)
3.构建查找值所在的数组
=$E$2&COUNTIF(INDIRECT("B2:B"&ROW($B$2:$B$27)),$E$2)

4.构建vlookup函数新的数据源
=IF({1,0},$E$2&COUNTIF(INDIRECT("B2:B"&ROW($B$2:$B$27)),$E$2),$C$2:$C$27)
5.完成vlookup一对多查询
=IFERROR(VLOOKUP($E$2&ROW(A2),IF({1,0},$E$2&COUNTIF(INDIRECT("B2:B"&ROW($B$2:$B$27)),$E$2),$C $2:$C$27),2,),"")

=IFERROR(VLOOKUP($D$2&ROW(A1),IF({1,0},$D$2&COUNTIF(INDIRECT("a2:a"&ROW($A$2:$A$27)),$D$2),$B $2:$B$27),2,),"")


---------------------------------------

函数高级第6讲:TEXT函数

例一:提取数值(数值为小数)

转置函数:transpose:
作用:将数组或单元格区域停止行列转置显现,必需用数组命令完毕
参数:需求停止转置的数组或工作表上的单元格区域

公式:=MAX(--TEXT(MID(A4,ROW($1:$20),TRANSPOSE(ROW($1:$20))),"G/通用格式;-G/通用格式;G/通用格式 ;!0"))

1.应用mid停止矩阵提取,得到数值,且可以提取出来小数。
2.应用text将文本转为0,则就不影响数值的提取了。
3.这里text格式不能简单的用"0;-0;0;!0" ,由于我们要提取的是小数,而格式假设用0则表示将小数停止取 整了。
4.text第二参数格式:运用G/通用格式 可以通用与整数与小数。
5.用最大值函数停止提取即可得到数值。


也可以用=SUM(--(0&MID(A14,ROW($1:$19),1))),重点为0&的运用。
----------------------------------------------------------------------

案例二:从身份证提取年龄--提取年份

公式:=DATEDIF(--TEXT(MID(A9,7,11)-500,"0-00-00,"),TODAY(),"y")

1.
mid提取年份,但是这里多提取了3位,公式后期会运用到,所以这里先记得这么提取的。

2.mid提取出来的伪年份 的后三位数据规律:要么大于等于500,要么小于500
        大于等于500 :减500时分是可以减开的。不触及到借位问题,也不会影响年份本领数据
        小于500:减500时分是减不开的,会触及到借位问题。招致年份中的日信息小一天了。而剩余数据 大于500
3.text千位分隔符用法中会触及到四舍五入问题。
4.text结果直接转负运算得到日期的序列码,15位身份证号的年份系统会自动辨以为19年份的。
5.年龄公式:datedif完成
=DATEDIF(--TEXT(MID(A9,7,11)-500,"0-00-00,"),TODAY(),"y")

----------------------------------------------
案例三: 为什么公式=TEXT("5-29","0") 返回 42264

1.5-29在系统中被辨以为日期,且是本年分中的5-29日。

2.0为数字占位符,第二参数运用"0",则结果按序列码格式显现日期

3.很多函数参数中假设只用,则表示参数启用的是0,但是这里千万不要这样简写。
        第二参数假设只打,号,则表示不显现数值节,默许显现文本值。所以这里不要把第二参数简写。
4.我们假设想显现为日期格式可以经过转负运算再设置为日期格式即可。

--------------------------------------------------
案例四:计算总通话时长

公式:=SUM(--TEXT({"0时0分","0时"}&D21:D28,"h:m:s;;0;!0")) 在经过自定义单元格格式调整为[m]:s格 式既可以显现为分秒格式了。

1.标准的时间格式:时分秒格式也就是0时0分0秒格式。
2.数据源中的通话时长我们需求转为标准时间格式再计算。

        a,关于有分秒的我们只需求在前面衔接0时,将其转为标准时间,但是关于秒而言则还是错误值。
        b,关于只需秒的我们需求在前面衔接0时0分,将其转为标准时间,但是关于分秒而言则是错误值。
3.要转为标准时间我们做的处置需求为两种情况停止衔接,而数据源为一维纵向,所以我们的两种时间格式 要用一维横向,
(        不可以用一维纵向,否则两个一维纵向运算时分需求维度分歧。)
        ={"0时0分","0时"}&D21:D28
4.关于错误值的日期格式我们晓得它们都是文本格式,所以经过text强迫将文本转为0,在停止计算就不会影 响计算了
=SUM(--TEXT({"0时0分","0时"}&D21:D28,"h:m:s;;0;!0"))


----------------------------------------------------------------------------

案例五:华诞提示
=TEXT(TEXT(TEXT(MID(A37,7,8),"0-00-00"),"m-d")-TEXT(TODAY(),"m-d"),"0天后华诞;华诞过了0天;华诞 快乐;@")

-----------------------------------
案例六:请求:当我的方案量超越上限我想 -1000,否则投入量为方案量

=A46-TEXT(A46,"[>1000]1;!0")*1000


---------------------------------------

函数高级第7讲:去反复值专讲

一:单列去反复值
        在数据源中没有空格情况下
        公式一:
=IFERROR(INDIRECT("a"&SMALL(IF(MATCH($A$2:$A$10,$A$2:$A$10,)=ROW($A$1:$A$9),ROW($A$2:$A $10)),ROW(A1))),"")
        公式二:
=INDIRECT("a"&MATCH(,COUNTIF($C$1:C1,$A$2:A10),)+1)&""
=INDEX($A$2:$A10,MATCH(,COUNTIF($C$1:C1,$A$2:$A10),))&""
=IFERROR(INDEX($A$2:$A$10,MATCH(,COUNTIF($C$1:C1,$A$2:$A$10),)),"")
        在数据源有空格存在情况下
        公式一:
=IFERROR(INDIRECT("a"&SMALL(IF((MATCH($A$2:$A$11&"",$A$2:$A$11&"",)=ROW($A$2:$A$11)-1)*($A $2:$A$11<>""),ROW($A$2:$A$11)),ROW(A1))),"")

公式思绪:
1.找到索要数据所在位置,留意,这里多一个条件,还要单元格区域不能为空。
(MATCH($A$2:$A$11&"",$A$2:$A$11&"",)=ROW($A$2:$A$11)-1)*($A$2:$A$11<>"")
公式构造:(位置)*(不为空)

2.IF返回契合条件的数据在单元格区域的位置序号
IF((MATCH($A$2:$A$11&"",$A$2:$A$11&"",)=ROW($A$2:$A$11)-1)*($A$2:$A$11<>""),ROW($A$2:$A$11))

3.small将契合条件的数据位置序号停止提取
SMALL(IF((MATCH($A$2:$A$11&"",$A$2:$A$11&"",)=ROW($A$2:$A$11)-1)*($A$2:$A$11<>""),ROW($A$2: $A$11)),ROW(A1))

4.indirect函数停止提取数据
INDIRECT("a"&SMALL(IF((MATCH($A$2:$A$11&"",$A$2:$A$11&"",)=ROW($A$2:$A$11)-1)*($A$2:$A $11<>""),ROW($A$2:$A$11)),ROW(A1)))

5.屏蔽下错误值(由于契合条件的数据都提取到了。再下来就没有契合条件的数据序号了,所以报错)
=IFERROR(INDIRECT("a"&SMALL(IF((MATCH($A$2:$A$11&"",$A$2:$A$11&"",)=ROW($A$2:$A$11)-1)*($A $2:$A$11<>""),ROW($A$2:$A$11)),ROW(A1))),"")


公式二:
=IFERROR(INDIRECT("a"&MIN(IF(($A$2:$A$11<>"")*(COUNTIF($C$1:C1,$A$2:$A$11)=0),ROW($A$2:$A $11)))),"")
IF返回来的0表示不要的数据,1表示要的数据,
countif公式下来后,数据源为两个单元格时分,其实数据源如今曾经是包括佛山小老鼠了,所以这里的 countif返回的结果中佛山小老鼠位置为1,其1<>""0 所以返回的是false,此时双条件 * 时分就将佛山 小老鼠屏蔽为 0 ,那么丫头的位置为我们所需求的数据中最小位置数据。
这里我们用min而不用small。

--------------------------------------------------
多列去反复值

公式:=IFERROR(INDIRECT(TEXT(MIN(IF(($A$2:$B$11<>"")*(COUNTIF($D$1:D1,$A$2:$B$11)=0),ROW($A $2:$A$11)*10000+COLUMN($A$1:$B$1))),"R0C0000"),),"")

思绪:
1.双条件得到想要的数据
($A$2:$B$11<>"")*(COUNTIF($D$1:D1,$A$2:$B$11)=0)

2.IF提取索要数据的行和列信息
这里对行停止加权处置,便当后期对行列的分割
IF(($A$2:$B$11<>"")*(COUNTIF($D$1:D1,$A$2:$B$11)=0),ROW($A$2:$A$11)*10000+COLUMN($A$1:$B$1))

3.min得到想要数据的第一条单元格地址
MIN(IF(($A$2:$B$11<>"")*(COUNTIF($D$1:D1,$A$2:$B$11)=0),ROW($A$2:$A$11)*10000+COLUMN($A$2: $B$2)))

4.text将单元格地址转为R0C000格式。

TEXT(MIN(IF(($A$2:$B$11<>"")*(COUNTIF($D$1:D1,$A$2:$B$11)=0),ROW($A$2:$A$11)*10000+COLUMN ($A$2:$B$2))),"r0c0000")
5.indirect提取数据
=INDIRECT(TEXT(MIN(IF(($A$2:$B$11<>"")*(COUNTIF($D$1:D1,$A$2:$B$11)=0),ROW($A$2:$A$11) *10000+COLUMN($A$2:$B$2))),"r0c0000"),)

--------------------------------------------------

第8讲加权专讲

提示:为了防止收个数字是 0 而招致最终相加时分0没有提取到,我们做1&a1 停止防止此错误发作

1.将每个字符单独提取出来
        =MID(1&A1,row($1:$30),1)
2.判别是不是数字
        =ISNUMBER(-MID(1&A1,ROW($1:$30),1))
3.提取位置
        =IF(ISNUMBER(-MID(1&A1,ROW($1:$30),1)),row($1:$30))
4.判别数字个数
        ROW(INDIRECT("1:"&COUNT(-MID(1&A1,ROW($1:$30),1))))
5.small将数字位置全部提取出来
        =SMALL(IF(ISNUMBER(-MID(1&A1,ROW($1:$30),1)),ROW($1:$30)),ROW(INDIRECT("1:"&COUNT(- MID(1&A1,ROW($1:$30),1)))))
6.将字符串中的数字全部提取出来
        =MID(1&A1,SMALL(IF(ISNUMBER(-MID(1&A1,ROW($1:$30),1)),ROW($1:$30)),ROW(INDIRECT ("1:"&COUNT(-MID(1&A1,ROW($1:$30),1))))),1)

7.对数字停止加权
        7.1判别数字个数
        ROW(INDIRECT("1:"&COUNT(-MID(1&A1,ROW($1:$30),1))))

        7.2按照10的倍数停止加权,并且是前面数字比后面数字的权限要大,才干做到相加时分位置不 变。这样就要对10的倍数停止倒序加权也就是10,9,8,7,6,5,4,3,2,1的次第加权。

        10^(count数字个数-row())
10^(COUNT(-MID(1&A1,ROW($1:$30),1))-ROW(INDIRECT("1:"&COUNT(-MID(1&A1,ROW($1:$30),1)))))

8.sum 停止相加,但是不要肯定公式,假设数值太大显现的也是科学计数法格式。
9.用mid从sum结果第2个位置提取 99个,得到数字。

完好公式;
=MID(SUM(MID(1&A1,SMALL(IF(ISNUMBER(-MID(1&A1,ROW($1:$30),1)),ROW($1:$30)),ROW(INDIRECT ("1:"&COUNT(-MID(1&A1,ROW($1:$30),1))))),1)*10^(COUNT(-MID(1&A1,ROW($1:$30),1))-ROW (INDIRECT("1:"&COUNT(-MID(1&A1,ROW($1:$30),1)))))),2,99)


--------------------------------
求每列最后一个单元格数字之和

公式一:lookup
        =LOOKUP(9E+307,A:A)+LOOKUP(9E+307,B:B)+LOOKUP(9E+307,C:C)
公式二:错位
        =SUM(IF(A2:C6="",A1:C5))

公式三:多维援用
        =SUM(N(OFFSET(A1,SUBTOTAL(2,OFFSET(A1,1,COLUMN(A1:C1)-1,10)),COLUMN(A:C)-1,)))

公式四:加权
=SUM(MOD(LARGE(COLUMN(A1:C1)*10^6+IF(A1:C5<>"",ROW(A1:C5)*10^4+A1:C5,0),COLUMN(A1:C1)*5- 4),10^4))


--------------------------------------------------

函高第9讲sumif与countif高级用法

sumif与countif函数高级用法汇总

        4.一列多条件

                =SUM(SUMIF(A38:A44,{"小老鼠";"丫头"},B38:B44))
        5.多列求和1(错位法)
                =SUMIF(A47:C54,"小老鼠",B47)
        6.多列求和2
                sum解法:=SUM((B58:B61=B59)*(C58:D61))
                sumif解法 =SUM(SUMIF(B58:B61,"女",OFFSET(B58,0,{1;2})))
        7.错位 =SUMIF(A65:A73,"张三",A66:A74)

        8.求大于等于500且小于1000的和
                解法1:普通法 用了2个sumif  =SUMIF(B27:B34,">=500")-SUMIF(B27:B34,">=1000")
         3(B43:B49,{">=500",">=1000"},B43:B49)*{1,-1})
=SUMIFS(B43:B49,B43:B49,">=500",B43:B49,"<1000")

        9.多表多条件汇总
=SUM(SUMIF(INDIRECT({"一月","二月","三月"}&"!a:a"),B55:B56,INDIRECT({"一月","二月","三月"}

&"!b:b")))

        11.动态多工作表汇总
                A.不能把数据汇总原有的数据列上
                B.宏表函数:get.workbook(1)
                C.T(Now())'起到刷新作用
                =SUM(SUMIF(INDIRECT(MID(S,FIND("]",S)+1,99)&"!A:A"),C1,INDIRECT(MID(S,FIND

("]",S)+1,99)&"!B:B")))&T(NOW())


---------------------------------------------
Countif函数
        它有2个参数,第1参数只能用单元格区域,不支持数组
        建议大家经过offset,Indirect函数打破
        它的第2参数支持数组用法

        案例讲解 求A列,C列"小老鼠"的个数
                          解法1:=SUM(COUNTIF(OFFSET(A:A,0,{0;2}),"小老鼠"))
                        解法2:=SUM(COUNTIF(INDIRECT({"A:A","C:C"}),"小老鼠"))
        案例讲解:统计不及格和良好的人数
        =SUM(COUNTIF(A1:A9,">="&{0,60,70,80})*{1,-1,1,-1})
        =SUM(COUNTIF(A1:A9,">="&{0,60;70,80})*{1,-1;1,-1})
        =SUM(COUNTIF(A1:A9,">="&{0,60;70,80})*{1,-1})
        =SUM(COUNTIF(A1:A9,">="&{0,70;60,80})*{1;-1})

--------------------------------------------------

函高第10讲:多维援用案例讲解

一;countif高级用法
1.多表统计个数
        =SUM(COUNTIF(INDIRECT({"一月","二月","三月","四月"}&"!a:a"),A2))
        =SUM(COUNTIF(INDIRECT(TEXT(ROW($1:$12),"[dbnum1]d月")&"!A:A"),A2))

2.VLOOKUP函数一对多查询
        =IFERROR(VLOOKUP($F$2&ROW(A1),IF({1,0},$F$2&COUNTIF(INDIRECT("B2:B"&ROW($A$2:$A

$7)),$F$2),$C$2:$C$7),2,),"")
        =IFERROR(VLOOKUP($E$2&ROW(A1),CHOOSE({1,2},$E$2&COUNTIF(OFFSET($A$2,,,ROW($A$2:$A

$7)-1,1),$E$2),$B$2:$B$7),2,),"")
阶梯式提取:
        =OFFSET($B$1,1,0,ROW($1:$6),1)
        =INDIRECT("a2:A"&ROW($A$2:$A$7))

二:多表动态条件汇总
        =SUM(SUMIF(INDIRECT(表名&"!a:a"),C1,INDIRECT(表名&"!b:b")))
1.公式不要录入在a列,否则进入循环援用。
2.公式也不要录入B列,假设录入在B列,那么当在同纬度的A列有条件“小老鼠”时分,公式得到的结果

是0.固然F9看是有正确结果
3.以上两种情况都必需启用迭代运算才干够看到结果。

4.当工作薄或工作表称号中有特殊符号时分,大家记得做容错处置:
        =SUM(SUMIF(INDIRECT("'"&表名&"'!A:A"),C1,INDIRECT("'"&表名&"'!B:B")))
        在工作表名前后添加单引号惹起来。

--------------------------------------------------

函高第11讲:提取数字专讲A

案例一:数字在左边
        方法一:=LEFT(B2,2*LEN(B2)-LENB(B2))

        .方法二:=LEFT(B2,COUNT(N(INDIRECT("P"&MID(B2,ROW($1:$19),1)))))

        方法三:=LEFT(B2,COUNT(-LEFT(B2,ROW($1:$19))))
                =LEFT(B2,COUNT(-MID(B2,ROW($1:$10),1)))

        方法四:=LEFT(B2,MATCH(2,LENB(MID(B2,ROW($1:$19),1)),)-1)

        方法五:=-LOOKUP(,-LEFT(B2,ROW($1:$19)))

        方法六:=REPLACE(B2,2*LEN(B2)-LENB(B2)+1,99,"")

        方法七:=LEFT(B2,MATCH(1,MID(B2,ROW($1:$19),1)*0))

        方法八:=MAX(--TEXT(LEFT(B2,ROW($1:$19)),"0;-0;0;!0"))

        方法九:=MAX(IFERROR(--LEFT(B2,ROW($1:$19)),0))

        方法十:=LEFT(B2,MATCH(9E+307,-MID(B2,ROW($1:$20),1)))
                =LEFT(B2,MATCH(1,0/MID(B2,ROW($1:$10),1)))

案例二:数字位置不肯定
        公式:肯定第一个数字位置,与统计数字个数  【提示:此公式不适宜小数存在情况。会出错】

=MID(A2,MIN(FIND(ROW($1:$10)-1,A2&5/19)),COUNT(-MID(A2,ROW($1:$20),1)))

        公式:肯定第一个数字位置后停止数组提取,lookUp提取最后一个有效数据
=LOOKUP(,-MID(A2,MIN(FIND(ROW($1:$10)-1,A2&5/19)),ROW($1:$10)))  【提示:此公式适宜有小数】


案例三:分隔提取
        =TRIM(MID(SUBSTITUTE($A2,"*",REPT(" ",99)),COLUMN(A1)*99-98,99))


--------------------------------------------------

函数高级第12讲:提取数字专讲B
公式:
=IFERROR(-LOOKUP(1,-MID("吖"&$A2,SMALL(IF(ISNUMBER(-RIGHT(TEXT(MID("吖"&$A2,ROW($1:$25),2),))),ROW($1:$25)),COLUMN(A1))+1,ROW($1:$10))),"")

--------------------------------------------------
函数高级第13讲:宏表函数与超链接制造


Ctrl+F3是定义称号的快捷键
--------------------------------------
一:get.cell

get.cell函数
作用:返回关于格式化,位置或单元格内容的信息。在由特定单元格状态决议行为的宏中,使
用GET.CELL。

例如:

24 是1-56的一个数字,代表单元格中第一个字符的字体颜色。假设字体颜色为自动生成,返回0。
41 不经翻译返回活动单元格中的公式。      
=SUBSTITUTE(提取公式,"=","")

62 返回工作簿和"[book1]sheet1"方式的当前表的文件名。【注:应为“活开工作表”】  

63 返回单元格的填充(背景)颜色。        
定义:颜色 =GET.CELL(63,按颜色排序!$A2)

66 返回包含BOOK1.XLS 方式的工作簿的称号。
===
GET.CELL函数  (在定义称号中运用)
GET.CELL(type_num, reference)
第一参数:指明单元格需求返回的信息的类型,用数字表示范围为1-66。
第二参数:提供信息的单元格,即单元格地址
留意:该函数返回的是单元格的信息,不是返回的单元格内容。
首先需求定义称号
--
1、返回活开工作表称号
定义称号:表名=GET.CELL(62,按颜色求和!$B$42) 第二参数为活开工作表恣意单元格
公式:=MID(表名,FIND("]",表名)+1,99)
        =REPLACE(表名,1,FIND("]",表名),)

2、返回当前工作薄称号
公式:=MID(表名,2,FIND("]",表名)-2)

方法2,66就是返回当前工作薄称号
        定义称号:MC=GET.CELL(66,GET.CELL!A1) 第二参数为恣意单元格
        工作薄称号公式:=MC
3、提取公式
定义称号选公式所在单元格,可以根据公式的变化而变化。
=get.cell(41,按颜色求和!$b30)
=SUBSTITUTE(公式,"=",)

4、提取单元格底纹颜色(代码)
定义称号:底纹  =GET.CELL(63,GET.CELL!$B38) 63 颜色
留意:该函数不能返回条件格式设置的颜色。
-------------------------------------
        案例一:按字体颜色求和
        *1**24返回字体颜色;63返回单元格底纹颜色;41返回单元格公式;62返回当前工作表称号
        *2**提示:条件格式设置的颜色不适用,可以运用VBA来完成。

1.定义称号,留意光标位置放置在返回值所在单元格中,
2.辅助单元格完成颜色值返回
3.sumif按条件求和=SUMIF($B$2:$B$11,D2,$A$2:$A$11)



        案例二:按单元格底纹颜色求和

1.定义称号,留意光标位置放置在返回值所在单元格中,
2.辅助单元格完成颜色值返回
3.sumif按条件求和=SUMIF($B$16:$B$25,D17,$A$16:$A$25)

-------------------------------------------------
二:EVALUATE函数
Evaluate函数
作用:可以返回一个表达式结果
参数为单元格地址

EVALUATE(FORMULA_TEXT)  (需求计算的文本表达式) 宏表函数需求在定义称号中运用。
留意:运用EVALUATE函数,光标的位置必需放在公式结果的单元格。
步骤:将光标放在需求计算结果的单元格,翻开定义称号对话框、定义称号、点选需求计算的单元格(设置 援用方式)
      关闭对话框、点选需求计算结果的单元格输入"=定义好的称号"即可。
--------------
        案例一:计算文本表达式
1.定义称号,留意光标位置放置在返回值所在单元格中, 体积=EVALUATE(计算不等式!$E2)
2.公式=体积

拓展:技巧完成计算
file:///C:\Users\ADMINI~1\AppData\Local\Temp\%W@GJ$ACOF(TYDYECOKVDYB.pnghttp://www.excelwm.net/forum.php ... tid=5786&fromuid=12
--------------------------------------------------
三:提取工作表称号 GET.WORKBOOK 函数

        公式:
=IFERROR(MID(INDEX(MySheets,1,ROW(A1),1),FIND("]",INDEX(MySheets,1,ROW(A1)),1)+1,99),"")
        一:GET.WORKBOOK函数
作用:返回工作薄信息
第一参数:指明要得到的工作簿信息类型的数
第二参数:是翻开的工作簿的名字。假设name_text被省略,默以为活开工作簿

参数应用说明:
1.=GET.WORKBOOK(1) 参数为1表示返回当前活开工作薄一切工作表称号集(程度数组返回)
("工作簿名+后辍+工作表名"的一维横向数组)
=GET.WORKBOOK(3)参数为3返回工作薄当前活开工作表称号
格式:("工作簿名+后辍+工作表名")
=GET.WORKBOOK(4)参数为4返回工作薄中表的数量。


2、提取工作表名:
公式1:=INDEX(表名,1,ROW(A1)) (转置)
公式:=IFERROR(MID(INDEX(表名,1,ROW(A1)),FIND("]",INDEX(表名,1,ROW(A1)))+1,99),"")&T(NOW())
为了即时更新衔接了易失性函数NOW,加T函数是为了将NOW函数的结果转为空。

也可以运用:
提取工作表称号
=IFERROR(REPLACE(INDEX(工作表集合,ROW(A1)),1,FIND("]",INDEX(工作表集合,ROW(A1))),),"")

3、提取工作簿名:
公式:=MID(INDEX(表名,1,1),2,FIND("]",INDEX(表名,1,1))-2)


还记不记得前面sumif那节课完成多表动态条件汇总,就是用到了宏表函数了。
=========================================================================

四、HYPERLINK函数
=HYPERLINK(link_location,friendly_name)
第一参数:工作簿途径、工作表称号。 ([工作簿称号.后缀].#工作表称号!单元格地址)
第二参数:单元格内显现的内容(可以起到解释说明)
留意:
第一参数是文本格式,也可以是文本字符串链接的单元格援用。
第二参数可以是数字,文本,定义称号等
假设链接不存在,将返回错误值
1、链接本工作表单元格
公式:=HYPERLINK("#单元格地址","显现文本")
2、跨表链接
公式:=HYPERLINK("#工作表名!单元格地址","显现文本")
3、跨工作簿链接
公式: =HYPERLINK("工作薄途径.#'工作表名'!单元格地址","显现内容")
=HYPERLINK("C:\Users\Administrator\Desktop\函数课件\周日函数高级班课件\丫头版函数高级课件\第13 节宏表函数与超链接.xlsx.#'sheet1-1'!a100","跳转")

4、超链接网页
公式:=HYPERLINK("file:///C:\Users\ADMINI~1\AppData\Local\Temp\%W@GJ$ACOF(TYDYECOKVDYB.pnghttp://www.excelwm.net","圆满论坛")
留意:制造网页超链接不用加"#"。上面的都需求加"#",作为启动开关。

制造目录:
=IFERROR(HYPERLINK("#'"&REPLACE(INDEX(工作表集合,ROW(A1)),1,FIND("]",INDEX(工作表集合,ROW(A1))),)&"'!a1",REPLACE(INDEX(工作表集合,ROW(A1)),1,FIND("]",INDEX(工作表集合,ROW(A1))),)),"")&T(NOW())

--------------------------------------------------
函数高级班第14讲:收款单填制


金额分格录入

方法一:
1.金额=数量*单价 财务中都是保存两位小数,这里我们也停止两位小数的保存
2.ROUND($C6*$D6,2)*100 保存两位小数并去小数点
3.补全位数:=MID("   "&ROUND($C6*$D6,2)*100,COLUMN(A1),1)
        效果二:=MID("  ¥"&ROUND($C6*$D6,2)*100,COLUMN(A1),1)
方法二:
3.=LEFT(RIGHT(" "&ROUND($C6*$D6,2)*100,9-COLUMN(A1))) 将没有金额位停止填充空,
4.假设想显现大写格式:=TEXT(LEFT(RIGHT(" "&ROUND($C6*$D6,2)*100,8-COLUMN(A1))),"[dbnum2]")
5.假设想在最前面一个无金额的位置填充¥,则公式为:
=LEFT(RIGHT(" ¥"&ROUND($C6*$D6,2)*100,9-COLUMN(A1)))
=TEXT(LEFT(RIGHT(" ¥"&ROUND($C6*$D6,2)*100,8-COLUMN(A1))),"[dbnum2]")

公式也可以运用=LEFT(RIGHT(" "&TEXT($C6*$D6,"0.00")*100,9-COLUMN(A1))) 效果一样的。
--------------------------------------------------------------------------------

合计金额小写:
=ROUND(SUMPRODUCT(C6:C9,D6:D9),2)

合计金额大写:
1.整数局部处置:=IF(INT(ABS(D10)),TEXT(INT(ABS(D10)),"[dbnum2]")&"元","")
2.小数局部处置
        2.1金额保存两位小数,=ROUND(SUMPRODUCT(C6:C9,D6:D9),2)  
我们运用TEXT(SUMPRODUCT(C6:C9,D6:D9),"0.00")
两个公式的区别:在取小数时分,一个可以取到 0 一取不到0.

        2.2.提取小数局部
        =RIGHT(TEXT(SUMPRODUCT(C6:C9,D6:D9),"0.00"),2)



完好公式:
=IF(D10<0,"负","")&IF(INT(ABS(D10)),TEXT(INT(ABS(D10)),"[dbnum2]")&"元","")&IF(INT(D10)=D10," 整",SUBSTITUTE(SUBSTITUTE(TEXT(RIGHT(TEXT(ABS(D10),"0.00"),2),"[dbnum2]0角0分"),"零分","整")," 零角","零"))

----------------------------------------

函高第15节SUBTOTA和FREQUENCY专讲


函数SUBTOTAL
        第1参数 如4 Max 就相当于普通的max
                如104 Max 也是相当于普通的max,但是它不包括躲藏的行
        案例讲解:
求和躲藏行的和(备注)躲藏了第11行
        =SUBTOTAL(109,B10:B12)

        案例讲解:
                在挑选的状态下如何让编号自动正确更新
                =SUBTOTAL(103,$C$21:C22)-1
                备注:大家要选择C21,选择表头,否则会把最一个行挑选到
        案例讲解,评分
                 第1参数支持数组用法
                 普通的解法 =(SUM(C35:G35)-MAX(C35:G35)-MIN(C35:G35))/3
                 数组的解法 =SUM((SUBTOTAL({9,4,5},C35:G35)*{1,-1,-1}))/3
        案例讲解 降维的作用
                 =SUM(SUBTOTAL(103,(INDIRECT("B"&(B45:B53<>"佛山小老鼠")/1%%+ROW(B45:B53)))))
                        offset,indirect index它们是返回是单元格,F9或者你运算返回单元格详细的值

函数:FREQUENCY 频率
        参数讲解
                两个参数,第1参数数据源;第2参数条件
                要留意的学问点:
                        1.两个参数都可以单元格区域;或者是数组
                        2.第2参数小于等于分隔点
                        3.第2参数假设有反复的,第一次呈现显现,后面全部显现0
                        4.返回的结果比第2参数个数还要多一个,如第2参数{60,70,80}返回4个
                        {59.9,60.9,70.9,80.9}返回5个
                        5.多的这个是第2参数最大的那个,不管它在那个位置,都会把显现最后
                        假设你第2参数不排序,它运算也会按升序排序停止,但是显现结果是
                        按你第2参数显现次第显现
        案例讲解
                案例一:统计小60的个数;大于等于60小于70的个数;大于等于70且小于80的个数,大于等于80的个数   
                =FREQUENCY(B7:B17,{59.99;69.9;79.9})
        案例讲解
                统计下面数字不反复的个数
                =COUNT(1/FREQUENCY(D27:D33,D27:D33))
        案例讲解统计下面的姓名不反复值的个数,有文本
                =COUNT(1/(FREQUENCY(MATCH(D40:D48&"",D40:D48&"",),ROW(1:9))*(D40:D48<>"")))
                =SUM(1/COUNTIF(D40:D48,D40:D48&"")*(D40:D48<>""))

函高第16节MMult函数专讲

MMULT
        参数讲解 (array1,array2)两个参数,参数算少的
        两个参数支持数组,单元格援用区域
        要留意的学问点
                第1点:第1参数的列数一定要等于第2参数的行数,否则报错
                第2点:两个参数里值只能是数值型数字,不能是true,False,文本也不行
                        当然文本型的数值也不行
                第3点:mmult得到的结果是由第1参数的行数,第2参数的列数组成一个新的数组,当然也可以是
                        一个元素
案例讲解1:求每一个学员的总分
        =MMULT(C11:E13,{1;1;1})
        =MMULT({1,1,1},E21:H23)
        总结一下MMult函数的运算原理
                第一参数的每一行里的每一个元素分别与第2参数每一列里每一个单元格分别相乘,
                最后把相乘的结果再相加
案例讲解2:让学员理解MMult运算原理
                =MMULT({60,70,80;50,60,70;80,90,100},{1,2;1,3;1,4})得到是一个3行2列的一个新的数组
                {210,650;180,560;270,830}
案例讲解3:单条件求和
        这是我们用sumif得到的=SUMIF($A$32:$A$37,D32,$B$32:$B$37)
        我们的目的是经过这个例子来理解MMult函数
        =MMULT(N(TRANSPOSE($A$32:$A$37=D32)),$B$32:$B$37)
案例讲解4:多条件求和
        sumifs解法:=SUMIFS($C$43:$C$54,$A$43:$A$54,$E43,$B$43:$B$54,F$42)
        sum也可以解=SUM(($A$43:$A$54=$E43)*($B$43:$B$54=F$42)*($C$43:$C$54))
        SUMPRODUCT解法=SUMPRODUCT(($A$43:$A$54=$E43)*($B$43:$B$54=F$42)*($C$43:$C$54))
        =MMULT(TRANSPOSE(($A$43:$A$54=$E43)*($B$43:$B$54=F$42)),$C$43:$C$54)
        经过上面学习,大家会发现,MMult函数第1参数,第2参数的构建是一个难点
        不过大家不要焦急,死咬着那一句话---"第1参数的列数一定要等于第2参数的行数,否则报错"
案例讲解5:多行多列查找
        =INDEX(B60:G62,MATCH(1,MMULT(N(B60:G62=B67),TRANSPOSE(COLUMN(B60:G60)^0)),),MATCH(1,MMULT(TRANSPOSE(N(B60:G62=B67)),{1;1;1}),)+1)
        =INDEX(B60:G62,MATCH(1,MMULT(N(B60:G62=B67),TRANSPOSE(COLUMN(B60:G60)^0)),),MATCH(1,MMULT(TRANSPOSE(N(B60:G62=B67)),row(B60:B62)^0),)+1)
案例讲解6:找出每个销售员前4大的的销量最大值
        关键是large函数第2参数还可以用二维数组
        =MAX(MMULT(MOD(LARGE(C71:L75+ROW(C71:C75)/1%%%,((76-ROW(C71:C75))*10)-{9,8,7,6}),10^6),{1;1;1;1}))
函高第17节兼并单元格条件求和专讲


 

                                                  


手机扫码浏览
问题咨询交流,不在线时,可以加我微信,微信号18664243619
函数、VBA、透视表交流学习QQ群2801--7317--4,我的电话18664243619,我的QQ732243800,更多的学习也可以关注我们的公众号:vba18664243619
回复

使用道具 举报

588

积分

0

技术分

0

鲜花

中级会员

Rank: 3Rank: 3

财富币
6827
学费币
0
推广币
75
学员红花
0
注册时间
2014-12-21
    购买在线课件和视频
    报班咨询联系电话
    Tel:186-6424-3619
    联系人:佛山小老鼠
    在线网络开设YY班级
    函数初级班
    函数中级班
    函数高级班
    VBA编程初级班
    VBA编程中级班
    VBA编程高级班
    透视表班
    290集视频
    525集excel视频大全
    189集免费excel视频
发表于 2015-11-18 08:09:03 | 显示全部楼层
回复 支持 反对

使用道具 举报

8

积分

0

技术分

0

鲜花

初级会员

Rank: 2

财富币
35
学费币
0
推广币
0
学员红花
0
注册时间
2015-12-8
    购买在线课件和视频
    报班咨询联系电话
    Tel:186-6424-3619
    联系人:佛山小老鼠
    在线网络开设YY班级
    函数初级班
    函数中级班
    函数高级班
    VBA编程初级班
    VBA编程中级班
    VBA编程高级班
    透视表班
    290集视频
    525集excel视频大全
    189集免费excel视频
发表于 2015-12-8 12:17:35 | 显示全部楼层
回复 支持 反对

使用道具 举报

5

积分

0

技术分

0

鲜花

初级会员

Rank: 2

财富币
41
学费币
0
推广币
0
学员红花
0
注册时间
2015-10-27
    购买在线课件和视频
    报班咨询联系电话
    Tel:186-6424-3619
    联系人:佛山小老鼠
    在线网络开设YY班级
    函数初级班
    函数中级班
    函数高级班
    VBA编程初级班
    VBA编程中级班
    VBA编程高级班
    透视表班
    290集视频
    525集excel视频大全
    189集免费excel视频
发表于 2015-12-18 12:24:43 | 显示全部楼层
回复 支持 反对

使用道具 举报

您需要登录后才可以回帖 登录 | 立即注册

本版积分规则 快速回帖:

最近新开的班级:2018-6-11开函数初级班,周一、周三、周五晚上8点到10点上课      立即注册  登录 

手机微信——扫一扫 关注完美论坛公众号天天收到Excel分享

QQ|微信绑定|Archiver|手机版|Excel完美论坛 ( 粤ICP备14102225号  

GMT+8, 2018-6-18 06:04 , Processed in 0.241855 second(s), 60 queries .

Powered by Discuz! X3.2

© 2001-2013 Comsenz Inc.

快速回复 返回顶部 返回列表